home *** CD-ROM | disk | FTP | other *** search
/ Ham Radio 2000 #2 / Ham Radio 2000 - Volume 2.iso / HAMV2 / MISC / HCAL-27 / ATTENPAD.BAS (.txt) < prev    next >
Encoding:
GW-BASIC  |  1997-01-27  |  12.1 KB  |  482 lines
  1. 10  'ATTENPAD - TEE & PI attenuator pads - 05 JUN 95 rev. 27 SEP 96
  2. 20  IF EX$=""THEN EX$="EXIT"
  3. 30  KEY OFF
  4. 40  DEFDBL P
  5. 50  COLOR 7,0,1
  6. 60  UL$=STRING$(80,205)
  7. 70  DIM STD(25)    'standard resistor base values
  8. 80  DIM RES(25)
  9. 90  DATA 10,11,12,13,15,16,18,20,22,24,27,30
  10. 100  DATA 33,36,39,43,47,51,56,62,68,75,82,91,100
  11. 110  FOR Z=1 TO 25:READ STD(Z):NEXT Z
  12. 120  CLS:GOTO 330
  13. 130  '
  14. 140  '.....nearest standard resistor
  15. 150  REM: REX = exact resistor value
  16. 160  REM: NSR = nearest standard resistor
  17. 170  MX=0.01      'multiplier
  18. 180  FOR Z=1 TO 25:RES(Z)=STD(Z)*MX:NEXT Z
  19. 190  '
  20. 200  FOR Y=1 TO 24:MID=(RES(Y)+RES(Y+1))/2
  21. 210  IF REX>=RES(Y)AND REX<=MID THEN NSR=RES(Y):GOTO 260
  22. 220  IF REX<=RES(Y+1)AND REX>MID THEN NSR=RES(Y+1):GOTO 260
  23. 230  NEXT Y
  24. 240  MX=MX*10:IF MX>=10^7 THEN NSR=22*10^6:GOTO 260
  25. 250  GOTO 180
  26. 260  RETURN
  27. 270  '
  28. 280  '.....format input line
  29. 290  U$="####.###":LOCATE CSRLIN-1:PRINT SPC(7);
  30. 300  LOCATE CSRLIN,47:PRINT STRING$(7,".");USING U$;Z;
  31. 310  RETURN
  32. 320  '
  33. 330  '.....start
  34. 340  CLS
  35. 350  COLOR 15,2
  36. 360  PRINT" ATTENUATORS: T-Pad and Pi-Pad";TAB(62);"by Bob Stein W6NBI ";
  37. 370  PRINT STRING$(80,32);
  38. 380  LOCATE CSRLIN-1,20:PRINT "edited for HAMCALC by George Murphy VE3ERP"
  39. 390  COLOR 1,0:PRINT STRING$(80,223);
  40. 400  COLOR 7,0
  41. 410  PRINT TAB(8);
  42. 420  PRINT "This program computes resistance values and power dissipation in"
  43. 430  PRINT TAB(8);
  44. 440  PRINT "constant-impedance TEE and PI attenuator pads."
  45. 450  PRINT
  46. 460  PRINT TAB(8);
  47. 470  PRINT "For minimum loss: R2 in the T-pad approaches zero, and R4 in the"
  48. 480  PRINT TAB(8);
  49. 490  PRINT "Pi-pad approaches infinity, effectively making them L-pads."
  50. 500  PRINT UL$;
  51. 510  LN=CSRLIN
  52. 520  TM= 8:LOCATE LN:GOSUB 2810    'diagrams
  53. 530  TM=44:LOCATE LN:GOSUB 2930
  54. 540  PRINT UL$;
  55. 550  COLOR 0,7:LOCATE CSRLIN,22
  56. 560  PRINT " Press 1 to continue or 0 to EXIT....."
  57. 570  COLOR 7,0
  58. 580  Z$=INKEY$:IF Z$=""THEN 580
  59. 590  IF Z$="0"THEN CLS:RUN EX$
  60. 600  IF Z$="1"THEN 630
  61. 610  GOTO 580
  62. 620  '
  63. 630  CLS
  64. 640  TM= 8:LOCATE 1:GOSUB 2810     'diagrams
  65. 650  TM=44:LOCATE 1:GOSUB 2930
  66. 660  PRINT UL$;
  67. 670  INPUT " ENTER: Terminating Resistance Z(Hi).......... (ohms)";ZH
  68. 680  IF ZH<=0 THEN BEEP:GOTO 630
  69. 690  Z=ZH:GOSUB 280:PRINT " -"
  70. 700  INPUT " ENTER: Terminating Resistance Z(Lo).......... (ohms)";ZL
  71. 710  IF ZL<=ZH THEN 760
  72. 720  BEEP:PRINT " Z(Lo) MUST BE EQUAL TO OR LESS THAN Z(Hi), BUT NOT ZERO"
  73. 730  PRINT " Press any key..........."
  74. 740  IF INKEY$=""THEN 740
  75. 750  CSR=CSRLIN-3:VIEW PRINT CSR TO 24:CLS:VIEW PRINT:LOCATE CSR:GOTO 630
  76. 760  Z=ZL:GOSUB 280:PRINT " -"
  77. 770  A=((SQR(ZH/ZL)+SQR((ZH/ZL)-1))^2)
  78. 780  ML=10*(LOG(A)/LOG(10)) : ML=INT(100*(ML+0.5/100))/100
  79. 790  PRINT "        Minimum Loss.................................";USING U$;ML;
  80. 800  PRINT " dB"
  81. 810  IF ML=0 GOTO 880
  82. 820  P=A
  83. 830  GOSUB 2550   'formulae
  84. 840  PRINT
  85. 850  PRINT TAB(28);"MINIMUM LOSS PADS  (effectively, L-pads)"
  86. 860  PRINT TAB(27);"THENTHENTHENTHENTHENTHENTHENTHENTHENTHENTHENTHENTHENTHENTHENTHENTHENTHENTHEN"
  87. 870  GOSUB 2690   'print values for minimum loss
  88. 880  PRINT
  89. 890  INPUT " ENTER: Required Loss............................(dB)";L
  90. 900  IF L>ML THEN 940
  91. 910  BEEP:PRINT" REQUIRED LOSS MUST BE GREATER THAN MIN. LOSS OF";ML;"dB"
  92. 920  GOTO 880
  93. 930  '
  94. 940  '.....calculation
  95. 950  CLS:PRINT
  96. 960  P=EXP((L/10)*LOG(10))
  97. 970  GOSUB 2550   'resistance formulas
  98. 980  TM= 8:LOCATE 1:GOSUB 2810   'diagrams
  99. 990  TM=44:LOCATE 1:GOSUB 2930   'diagrams
  100. 1000  PRINT UL$;
  101. 1010  GOSUB 2640  'calculate and print
  102. 1020  PRINT UL$;
  103. 1030  CSR=CSRLIN:GOSUB 4690
  104. 1040  LOCATE 25,1:PRINT STRING$(80,32);:LOCATE CSR
  105. 1050  '
  106. 1060  PRINT " If option <4> is run before option <3>, then option <3> will also";
  107. 1070  PRINT " calculate"
  108. 1080  PRINT " recommended resistor wattages."
  109. 1090  PRINT UL$;
  110. 1100  PRINT "        Press number in < > to:"
  111. 1110  PRINT UL$;
  112. 1120  PRINT "  < 1 > Change specified loss"
  113. 1130  PRINT "  < 2 > Change Impedances (Rerun)"
  114. 1140  PRINT "  < 3 > Determine exact Attenuation & Impedances using standard ";
  115. 1150  PRINT "value resistors"
  116. 1160  PRINT "  < 4 > Determine power dissipated in each resistor"
  117. 1170  PRINT "  < 5 > QUIT";
  118. 1180  Z$=INKEY$:IF Z$=""THEN 1180
  119. 1190  IF Z$="1"THEN LOCATE 24,8:GOTO 890
  120. 1200  IF Z$="2"THEN 120
  121. 1210  IF Z$="3"THEN LOCATE 24,8:GOTO 1260
  122. 1220  IF Z$="4"THEN LOCATE 24,8:GOTO 3050
  123. 1230  IF Z$="5"THEN 330   'start
  124. 1240  GOTO 1180
  125. 1250  '
  126. 1260  '.....exact attenuation & impedances for standard value resistors
  127. 1270  COLOR 0,7
  128. 1280  PRINT " For T-pad or Pi-pad?  (t/p) ";
  129. 1290  COLOR 7,0
  130. 1300  Z$=INKEY$:IF Z$=""THEN 1300
  131. 1310  IF Z$="T"OR Z$="t"THEN 1350
  132. 1320  IF Z$="P"OR Z$="p"THEN 1950
  133. 1330  GOTO 1300
  134. 1340  '
  135. 1350  CLS:LOCATE 1:TM=26:GOSUB 2810    'T-pad diagram
  136. 1360  PRINT UL$;
  137. 1370  IF I THEN GOSUB 3910
  138. 1380  GOSUB 4390:LOCATE 9
  139. 1390  OTHER$="Pi-pad"
  140. 1400  U$="####,###.#"
  141. 1410  T=42
  142. 1420  '
  143. 1430  REX=R1:GOSUB 140
  144. 1440  PRINT " R1 calculated value is";R1;"-";TAB(T);"Use: R1=";USING U$;NSR;
  145. 1450  PRINT " -";:W=W1:GOSUB 4440:PRINT W$:R11=NSR
  146. 1460  '
  147. 1470  REX=R2:GOSUB 140
  148. 1480  PRINT " R2 calculated value is";R2;"-";TAB(T);"Use: R2=";USING U$;NSR;
  149. 1490  PRINT " -";:W=W2:GOSUB 4440:PRINT W$:R22=NSR
  150. 1500  '
  151. 1510  REX=R3:GOSUB 140
  152. 1520  PRINT " R3 calculated value is";R3;"-";TAB(T);"Use: R3=";USING U$;NSR;
  153. 1530  PRINT " -";:W=W3:GOSUB 4440:PRINT W$:R33=NSR
  154. 1540  '
  155. 1550  RA=R22+ZL
  156. 1560  RB=RA*R33/(RA+R33)
  157. 1570  RC=R11+RB
  158. 1580  RD=R11+ZH
  159. 1590  RE=RD*R33/(RD+R33)
  160. 1600  RF=R22+RE
  161. 1610  PA=1/RC
  162. 1620  PB=((ZL/RA)*(RB/RC))^2/ZL
  163. 1630  ATI=10*LOG(PA/PB)/LOG(10)
  164. 1640  PC=1/RF
  165. 1650  PD=((ZH/RD)*(RE/RF))^2/ZH
  166. 1660  ATO=10*LOG(PC/PD)/LOG(10)
  167. 1670  SC=RC/ZH
  168. 1680  IF SC<1 THEN SC=1/SC
  169. 1690  SF=RF/ZL
  170. 1700  IF SF<1 THEN SF=1/SF
  171. 1710  PRINT
  172. 1720  PRINT " For";L;"dB T-pad using standard resistors shown above and ";
  173. 1730  PRINT "design values of:"
  174. 1740  PRINT
  175. 1750  PRINT TAB(25);"Z(Hi) =";ZH;"- and Z(Lo) =";ZL;"-"
  176. 1760  PRINT
  177. 1770  U$="####.##"
  178. 1780  PRINT "   Impedance looking into Z(Hi) =   ";USING U$;RC;
  179. 1790  PRINT " -.....VSWR =";USING "##.##";SC
  180. 1800  PRINT "   Impedance looking into Z(Lo) =   ";USING U$;RF;
  181. 1810  PRINT " -.....VSWR =";USING "##.##";SF
  182. 1820  PRINT
  183. 1830  PRINT "   Attenuation from Z(Hi) to Z(Lo) =";USING U$;ATI;:PRINT " dB"
  184. 1840  PRINT "   Attenuation from Z(Lo) to Z(Hi) =";USING U$;ATO;:PRINT " dB"
  185. 1850  CSR=CSRLIN
  186. 1860  PRINT
  187. 1870  COLOR 0,7
  188. 1880  PRINT " Do you want to see the ";OTHER$;" configuration?  (y/n) ";
  189. 1890  Z$=INKEY$:IF Z$=""THEN 1890
  190. 1900  COLOR 7,0
  191. 1910  IF Z$="N"OR Z$="n"THEN 4570
  192. 1920  IF Z$="Y"OR Z$="y"THEN 1950
  193. 1930  GOTO 1890
  194. 1940  '
  195. 1950  CLS:LOCATE 1:TM=26:GOSUB 2930    'Pi-pad diagram
  196. 1960  PRINT UL$;
  197. 1970  IF I THEN GOSUB 3910
  198. 1980  GOSUB 4390:LOCATE 10
  199. 1990  OTHER$="T-pad"
  200. 2000  U$="####,###.#"
  201. 2010  T=42
  202. 2020  '
  203. 2030  REX=R4:GOSUB 140
  204. 2040  PRINT " R4 calculated value is";R4;"-";TAB(T);"Use: R4=";USING U$;NSR;
  205. 2050  PRINT " -";:W=W4:GOSUB 4440:PRINT W$:R44=NSR
  206. 2060  '
  207. 2070  REX=R5:GOSUB 140
  208. 2080  PRINT " R5 calculated value is";R5;"-";TAB(T);"Use: R5=";USING U$;NSR;
  209. 2090  PRINT " -";:W=W5:GOSUB 4440:PRINT W$:R55=NSR
  210. 2100  '
  211. 2110  REX=R6:GOSUB 140
  212. 2120  PRINT " R6 calculated value is";R6;"-";TAB(T);"Use: R6=";USING U$;NSR;
  213. 2130  PRINT " -";:W=W6:GOSUB 4440:PRINT W$:R66=NSR
  214. 2140  '
  215. 2150  RG=R55*ZL/(R55+ZL)
  216. 2160  RH=RG+R66
  217. 2170  RI=R44*RH/(R44+RH)
  218. 2180  RJ=R44*ZH/(R44+ZH)
  219. 2190  RK=RJ+R66
  220. 2200  RL=R55*RK/(R55+RK)
  221. 2210  PE=1/RI
  222. 2220  PF=(RG/RH)^2/ZL
  223. 2230  API=10*LOG(PE/PF)/LOG(10)
  224. 2240  PG=1/RL
  225. 2250  PH=(RJ/RK)^2/ZH
  226. 2260  APO=10*LOG(PG/PH)/LOG(10)
  227. 2270  SI=RI/ZH
  228. 2280  IF SI<1 THEN SI=1/SI
  229. 2290  SL=RL/ZL
  230. 2300  IF SL<1 THEN SL=1/SL
  231. 2310  PRINT
  232. 2320  PRINT " For";L;"dB Pi-pad using standard resistors shown above and ";
  233. 2330  PRINT "design values of:"
  234. 2340  PRINT
  235. 2350  PRINT TAB(25);"Z(Hi) =";ZH;"- and Z(Lo) =";ZL;"-"
  236. 2360  PRINT
  237. 2370  U$="####.##"
  238. 2380  PRINT "   Impedance looking into Z(Hi) =   ";USING U$;RI;
  239. 2390  PRINT " -.....VSWR =";USING "##.##";SI
  240. 2400  PRINT "   Impedance looking into Z(Lo) =   ";USING U$;RL;
  241. 2410  PRINT " -.....VSWR =";USING "##.##";SL
  242. 2420  PRINT
  243. 2430  PRINT "   Attenuation from Z(Hi) to Z(Lo) =";USING U$;API;:PRINT " dB"
  244. 2440  PRINT "   Attenuation from Z(Lo) to Z(Hi) =";USING U$;APO;:PRINT " dB"
  245. 2450  CSR=CSRLIN
  246. 2460  PRINT
  247. 2470  COLOR 0,7
  248. 2480  PRINT " Do you want to see the ";OTHER$;" configuration?  (y/n) ";
  249. 2490  Z$=INKEY$:IF Z$=""THEN 2490
  250. 2500  COLOR 7,0
  251. 2510  IF Z$="N"OR Z$="n"THEN 4570
  252. 2520  IF Z$="Y"OR Z$="y"THEN 1350
  253. 2530  GOTO 2490
  254. 2540  '
  255. 2550  '.....Formulas for resistance values from ITT Handbook
  256. 2560  R3=2*SQR(P*ZH*ZL)/(P-1)
  257. 2570  R1=ZH*((P+1)/(P-1))-R3
  258. 2580  R2=ZL*((P+1)/(P-1))-R3
  259. 2590  R6=((P-1)*SQR(ZH*ZL/P))/2
  260. 2600  R4=1/((1/ZH)*(P+1)/(P-1)-(1/R6))
  261. 2610  R5=1/((1/ZL)*(P+1)/(P-1)-(1/R6))
  262. 2620  RETURN
  263. 2630  '
  264. 2640  'ABS variables in print statements eliminate negative values of unused
  265. 2650  'resistors in min. loss L-pads
  266. 2660  PRINT"       ";L;"dB T-Pad";TAB(33);"Z(Hi) =";ZH;"-";TAB(59);L;"dB Pi-Pad"
  267. 2670  PRINT TAB(33);"Z(Lo) =";ZL;"-"
  268. 2680  '
  269. 2690  U$="###,###.##"
  270. 2700  PRINT "        R1 =";USING U$;R1;:PRINT " -";TAB(53);"R4 =";
  271. 2710  IF ABS(R4)>10^7 THEN PRINT " (near infinity)":GOTO 2730
  272. 2720  PRINT USING U$;ABS(R4);:PRINT " -"
  273. 2730  PRINT "        R2 =";'USING U$;ABS(R2);:PRINT " -";TAB(53);"R5 =";
  274. 2740  IF ABS(R2)<0.000999999 THEN PRINT " (near zero)";:GOTO 2760
  275. 2750  PRINT USING U$;ABS(R2);:PRINT " -";
  276. 2760  PRINT TAB(53);"R5 =";USING U$;ABS(R5);:PRINT " -"
  277. 2770  PRINT "        R3 =";USING U$;R3;:PRINT " -";TAB(53);"R6 =";
  278. 2780  PRINT USING U$;R6;:PRINT " -"
  279. 2790  RETURN
  280. 2800  '
  281. 2810  '.....T-pad diagram
  282. 2820  COLOR 0,7
  283. 2830  LOCATE CSRLIN,TM:PRINT "                             "
  284. 2840  LOCATE CSRLIN,TM:PRINT "   SOUNDSOUNDSOUNDSOUND R1 SOUNDSOUNDSOUNDBSAVESOUNDSOUNDSOUND R2 SOUNDSOUNDSOUNDSOUND   "
  285. 2850  LOCATE CSRLIN,TM:PRINT "              CALL              "
  286. 2860  LOCATE CSRLIN,TM:PRINT " Z(Hi)SOUNDDEFDBL      R3     DEFSNGSOUNDZ(Lo) "
  287. 2870  LOCATE CSRLIN,TM:PRINT "              CALL              "
  288. 2880  LOCATE CSRLIN,TM:PRINT "   SOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDMOTORSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUND   "
  289. 2890  LOCATE CSRLIN,TM:PRINT "            T-Pad            "
  290. 2900  COLOR 7,0
  291. 2910  RETURN
  292. 2920  '
  293. 2930  '.....Pi-pad diagram
  294. 2940  COLOR 0,7
  295. 2950  LOCATE CSRLIN,TM:PRINT "                              "
  296. 2960  LOCATE CSRLIN,TM:PRINT "   SOUNDSOUNDSOUNDSOUNDSOUNDSOUNDBSAVESOUNDSOUNDSOUND R6 SOUNDSOUNDSOUNDBSAVESOUNDSOUNDSOUNDSOUNDSOUNDSOUND   "
  297. 2970  LOCATE CSRLIN,TM:PRINT "         CALL          CALL         "
  298. 2980  LOCATE CSRLIN,TM:PRINT " Z(Hi)SOUNDDEFDBL R4        R5 DEFSNGSOUNDZ(Lo) "
  299. 2990  LOCATE CSRLIN,TM:PRINT "         CALL          CALL         "
  300. 3000  LOCATE CSRLIN,TM:PRINT "   SOUNDSOUNDSOUNDSOUNDSOUNDSOUNDMOTORSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDSOUNDMOTORSOUNDSOUNDSOUNDSOUNDSOUNDSOUND   "
  301. 3010  LOCATE CSRLIN,TM:PRINT "            Pi-Pad            "
  302. 3020  COLOR 7,0
  303. 3030  RETURN
  304. 3040  '
  305. 3050  '.....Power dissipation calculations
  306. 3060  CLS
  307. 3070  PRINT
  308. 3080  PRINT "        Will input to pad be entered in (v)olts or (w)atts?  (v/w)"
  309. 3090  Z$=INKEY$:IF Z$=""THEN 3090
  310. 3100  IF Z$="V"OR Z$="v"THEN IP$="volts":GOTO 3150
  311. 3110  IF Z$="W"OR Z$="w"THEN IP$="watts":GOTO 3150
  312. 3120  GOTO 3090
  313. 3130  '
  314. 3140  GOTO 4120
  315. 3150  PRINT " ENTER: Input signal level applied to pad.....(";IP$;")";:INPUT I
  316. 3160  Z=I:GOSUB 280:PRINT " ";IP$
  317. 3170  PRINT "        Is input applied to (h)i or (l)o impedance port?  (h/l)"
  318. 3180  IZ$=INKEY$:IF IZ$=""THEN 3180
  319. 3190  IF IZ$="H" OR IZ$="h" THEN IZ$="Hi":GOTO 3220
  320. 3200  IF IZ$="L" OR IZ$="l" THEN IZ$="Lo":GOTO 3220
  321. 3210  GOTO 3180
  322. 3220  IF IZ$="Lo" THEN 3560 ELSE 3250
  323. 3230  GOTO 3180
  324. 3240  '
  325. 3250  '.....select pad for HI port input
  326. 3260  IF IP$="watts" THEN V=SQR(I*ZH) ELSE V=I
  327. 3270  COLOR 0,7:LOCATE CSRLIN,8
  328. 3280  PRINT " For T-pad or Pi-pad?  (t/p) ";
  329. 3290  COLOR 7,0
  330. 3300  ZP$=INKEY$:IF ZP$=""THEN 3300
  331. 3310  IF ZP$="T"OR ZP$="t"THEN 3350
  332. 3320  IF ZP$="P"OR ZP$="p"THEN 3450
  333. 3330  GOTO 1300
  334. 3340  '
  335. 3350  RE=R3*(R2+ZL)/(R3+R2+ZL)
  336. 3360  V3=V*RE/(RE+R1)
  337. 3370  V1=V-V3
  338. 3380  V2=V3*R2/(R2+ZL)
  339. 3390  GOSUB 3860
  340. 3400  CLS:LOCATE 1:TM=26:GOSUB 2810  'T-pad diagram
  341. 3410  GOSUB 4390
  342. 3420  GOSUB 3910
  343. 3430  GOTO 3970
  344. 3440  '
  345. 3450  RE=R5*ZL/(R5+ZL)
  346. 3460  V5=V*RE/(RE+R6)
  347. 3470  V6=V-V5
  348. 3480  W4=V*V/R4
  349. 3490  W5=V5*V5/R5
  350. 3500  W6=V6*V6/R6
  351. 3510  CLS:LOCATE 1:TM=26:GOSUB 2930  'Pi-pad diagram
  352. 3520  GOSUB 4390        'print Z(Hi) & Z(Lo)
  353. 3530  GOSUB 3910        'print results
  354. 3540  GOTO 4190         'print Pi-pad results
  355. 3550  '
  356. 3560  '.....select pad for LO port input
  357. 3570  IF IP$="watts" THEN V=SQR(I*ZL) ELSE V=I
  358. 3580  COLOR 0,7:LOCATE CSRLIN,8
  359. 3590  PRINT " For T-pad or Pi-pad?  (t/p) ";
  360. 3600  COLOR 7,0
  361. 3610  ZP$=INKEY$:IF ZP$=""THEN 3610
  362. 3620  IF ZP$="T"OR ZP$="t"THEN 3660
  363. 3630  IF ZP$="P"OR ZP$="p"THEN 3760
  364. 3640  GOTO 1300
  365. 3650  '
  366. 3660  RE=R3*(R1+ZH)/(R3+R1+ZH)
  367. 3670  V3=V*RE/(RE+R2)
  368. 3680  V2=V-V3
  369. 3690  V1=V3*R1/(R1+ZH)
  370. 3700  GOSUB 3860
  371. 3710  CLS:LOCATE 1:TM=26:GOSUB 2810  'T-pad diagram
  372. 3720  GOSUB 4390
  373. 3730  GOSUB 3910
  374. 3740  GOTO 3970
  375. 3750  '
  376. 3760  RE=R4*ZH/(R4+ZH)
  377. 3770  V4=V*RE/(RE+R6)
  378. 3780  V6=V-V4
  379. 3790  W4=V4*V4/R4
  380. 3800  W5=V*V/R5
  381. 3810  W6=V6*V6/R6
  382. 3820  CLS:LOCATE 1:TM=26:GOSUB 2930    'Pi-pad diagram
  383. 3830  GOSUB 4390
  384. 3840  GOSUB 3910
  385. 3850  GOTO 4190
  386. 3860  W1=V1*V1/R1
  387. 3870  W2=V2*V2/R2
  388. 3880  W3=V3*V3/R3
  389. 3890  RETURN
  390. 3900  '
  391. 3910  '.....text
  392. 3920  LOCATE 9,18
  393. 3930  PRINT "With";I;IP$;" applied to ";IZ$;"-Z port of";L;"dB pad:"
  394. 3940  PRINT
  395. 3950  RETURN
  396. 3960  '
  397. 3970  '.....T-pad
  398. 3980  T=16:U$="##,###.###"
  399. 3990  PRINT TAB(T);
  400. 4000  PRINT "R1 =";USING U$;ABS(R1);:PRINT " - @";USING U$;SQR(W1/R1);
  401. 4010  PRINT " amps =";USING U$;W1;:PRINT " watts"
  402. 4020  PRINT TAB(T);
  403. 4030  PRINT "R2 =";USING U$;ABS(R2);:PRINT " - @";USING U$;SQR(W2/R2);
  404. 4040  PRINT " amps =";USING U$;W2;:PRINT " watts"
  405. 4050  PRINT TAB(T);
  406. 4060  PRINT "R3 =";USING U$;ABS(R3);:PRINT " - @";USING U$;SQR(W3/R3);
  407. 4070  PRINT " amps =";USING U$;W3;:PRINT " watts"
  408. 4080  PRINT
  409. 4090  COLOR 0,7
  410. 4100  PRINT " Do you want to see the Pi-pad configuration?   (y/n) "
  411. 4110  COLOR 7,0
  412. 4120  Z$=INKEY$:IF Z$=""THEN 4120
  413. 4130  IF Z$="Y"OR Z$="y"THEN ZP$="p":GOTO 4170
  414. 4140  IF Z$="N"OR Z$="n"THEN 4570
  415. 4150  GOTO 4120
  416. 4160  '
  417. 4170  IF IZ$="Hi"THEN 3310 ELSE 3620
  418. 4180  '
  419. 4190  '.....Pi-pad
  420. 4200  T=16:U$="##,###.###"
  421. 4210  PRINT TAB(T);
  422. 4220  PRINT "R4 =";USING U$;ABS(R4);:PRINT " - @";USING U$;SQR(W4/R4);
  423. 4230  PRINT " amps =";USING U$;W4;:PRINT " watts"
  424. 4240  PRINT TAB(T);
  425. 4250  PRINT "R5 =";USING U$;ABS(R5);:PRINT " - @";USING U$;SQR(W5/R5);
  426. 4260  PRINT " amps =";USING U$;W5;:PRINT " watts"
  427. 4270  PRINT TAB(T);
  428. 4280  PRINT "R6 =";USING U$;ABS(R6);:PRINT " - @";USING U$;SQR(W6/R6);
  429. 4290  PRINT " amps =";USING U$;W6;:PRINT " watts"
  430. 4300  PRINT
  431. 4310  COLOR 0,7
  432. 4320  PRINT " Do you want to see the T-pad configuration?   (y/n) "
  433. 4330  COLOR 7,0
  434. 4340  Z$=INKEY$:IF Z$=""THEN 4340
  435. 4350  IF Z$="Y"OR Z$="y"THEN ZP$="t":GOTO 4170
  436. 4360  IF Z$="N"OR Z$="n"THEN 4570
  437. 4370  GOTO 4340
  438. 4380  '
  439. 4390  '.....display impedances in diagram
  440. 4400  LOCATE 4,12 : PRINT ZH;"- SOUNDSOUNDDEFDBL "
  441. 4410  LOCATE 4,58 : PRINT " DEFSNGSOUNDSOUND";ZL;"- "
  442. 4420  RETURN
  443. 4430  '
  444. 4440  '.....resistor rating
  445. 4450  W=W*1.5
  446. 4460  IF W>10 THEN W$=STR$(INT(W)+1)+" w."
  447. 4470  IF W<=10 THEN W$="10 w."
  448. 4480  IF W<=5 THEN W$="5 w."
  449. 4490  IF W<=2 THEN W$="2 w."
  450. 4500  IF W<=1 THEN W$="1 w."
  451. 4510  IF W<=0.5 THEN W$="RENUM w."
  452. 4520  IF W<=0.25 THEN W$="DEFSTR w."
  453. 4530  IF LEN(W$)<7 THEN W$=" "+W$:GOTO 4530
  454. 4540  IF W=0 THEN W$=""
  455. 4550  RETURN
  456. 4560  '
  457. 4570  '.....return to sub-menu
  458. 4580  LOCATE CSRLIN-1:PRINT STRING$(80,32);:GOSUB 4690:CLS
  459. 4590  LOCATE 1:TM= 8:GOSUB 2810   'T-pad diagram
  460. 4600  LOCATE 1:TM=44:GOSUB 2930   'Pi-pad diagram
  461. 4610  PRINT UL$;
  462. 4620  GOTO 1060
  463. 4630  '
  464. 4640  '.....end
  465. 4650  GOSUB 4690
  466. 4660  GOTO 330
  467. 4670  END
  468. 4680  '
  469. 4690  'HARDCOPY
  470. 4700  GOSUB 4810:LOCATE 25,2:COLOR 14,6
  471. 4710  PRINT " Press 1 to print screen, 2 to print screen & ";
  472. 4720  PRINT "advance paper, or 3 to continue.";:COLOR 7,0
  473. 4730  Z$=INKEY$:IF Z$="3"THEN GOSUB 4810:RETURN
  474. 4740  IF Z$="1"OR Z$="2"THEN GOSUB 4810:GOTO 4760
  475. 4750  GOTO 4730
  476. 4760  FOR QX=1 TO 24:FOR QY=1 TO 80
  477. 4770  LPRINT CHR$(SCREEN(QX,QY));
  478. 4780  NEXT QY:NEXT QX
  479. 4790  IF Z$="2"THEN LPRINT CHR$(12)
  480. 4800  GOTO 4700
  481. 4810  LOCATE 25,1:PRINT STRING$(80,32);:RETURN
  482.